From e7136be25751215392dc0e9a0fe59573d4ff69b4 Mon Sep 17 00:00:00 2001
From: Sandino Araico Sanchez <sandino@sandino.net>
Date: Mon, 24 Apr 2017 23:37:50 -0500
Subject: [PATCH] nghttp2-1.21.1.ebuild de portage

---
 net-libs/nghttp2/nghttp2-1.21.1.ebuild | 62 ++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 net-libs/nghttp2/nghttp2-1.21.1.ebuild

diff --git a/net-libs/nghttp2/nghttp2-1.21.1.ebuild b/net-libs/nghttp2/nghttp2-1.21.1.ebuild
new file mode 100644
index 0000000..3ec4b99
--- /dev/null
+++ b/net-libs/nghttp2/nghttp2-1.21.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+# TODO: Add python support.
+
+EAPI=6
+
+inherit multilib-minimal
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/tatsuhiro-t/nghttp2.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/tatsuhiro-t/nghttp2/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+DESCRIPTION="HTTP/2 C Library"
+HOMEPAGE="https://nghttp2.org/"
+
+LICENSE="MIT"
+SLOT="0/1.14" # <C++>.<C> SONAMEs
+IUSE="cxx debug hpack-tools jemalloc libressl static-libs test +threads utils xml"
+
+RDEPEND="
+	cxx? ( dev-libs/boost:=[${MULTILIB_USEDEP},threads] )
+	hpack-tools? ( >=dev-libs/jansson-2.5 )
+	jemalloc? ( dev-libs/jemalloc[${MULTILIB_USEDEP}] )
+	utils? (
+		>=dev-libs/libev-4.15[${MULTILIB_USEDEP}]
+		!libressl? ( >=dev-libs/openssl-1.0.2:0[-bindist,${MULTILIB_USEDEP}] )
+		libressl? ( dev-libs/libressl[${MULTILIB_USEDEP}] )
+		>=sys-libs/zlib-1.2.3[${MULTILIB_USEDEP}]
+		net-dns/c-ares:=[${MULTILIB_USEDEP}]
+	)
+	xml? ( >=dev-libs/libxml2-2.7.7:2[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( >=dev-util/cunit-2.1[${MULTILIB_USEDEP}] )"
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-examples \
+		--disable-failmalloc \
+		--disable-werror \
+		--without-cython \
+		--disable-python-bindings \
+		--without-spdylay \
+		$(use_enable cxx asio-lib) \
+		$(use_enable debug) \
+		$(multilib_native_use_enable hpack-tools) \
+		$(use_enable static-libs static) \
+		$(use_enable threads) \
+		$(multilib_native_use_enable utils app) \
+		$(multilib_native_use_with jemalloc) \
+		$(multilib_native_use_with xml libxml2)
+}
+
+multilib_src_install_all() {
+	use static-libs || find "${ED}"/usr -name '*.la' -delete
+}